How to sum in Microsoft Excel, with a simple SUM function, or formulas that sum based on criteria.

For quick overview, watch video: 7 ways to sum in Excel. Next, scroll down for more videos, written steps, and free Excel workbooks.

For a quick overview of 7 different ways to sum numbers with Excel functions, you can watch this 9-minute video. There are written steps and screen shots below the video, for all of the examples.

**Video Timeline** (blue links go to written steps below the video)

- 0:00 Introduction
- 0:09 1. Quick Grand Totals --
**Grand Total**a range of cells - 0:45 2. Sum Specific Cells -- Sum a
**simple range**of cells - 1:56 3. Running Total --
**Running Total** - 3:28 4. Sum Specific Items -- Sum cells that match
**one criterion** - 4:41 5. Sum Partial Match -- Match with
**wildcard** - 6:21 6. Sum With Multiple Criteria -- Sum cells that match
**multiple criteria** - 7:46 7. Sum in Filtered List -- Sum a Filtered List With
**SUBTOTAL** - 09:27 Get the Sample File -- Download the 7 Ways to
Sum
**sample file**

The quickest and easiest way to sum a range of cells is to use the Excel AutoSum button. It automatically enters an Excel SUM function in the selected cell. The SUM function totals one or more numbers in a range of cells.

The first example, below, shows how to use the AutoSum feature

- Select the blank cell in the row below the cells that you want to sum, cell A5 in this example.
- Click the
**AutoSum**command on the Ribbon's Home tab,

or use the keyboard shortcut:**Alt + =** - A SUM formula will appear in the active cell, with a reference to
the cells above. In the screen shot below, there is a SUM formula in
cell A5:
**=SUM(A1:A4)**

NOTE: If all cells are not automatically included, you can extend the frame, to select them. - Press the Enter key to complete the entry.

Instead of using the AutoSum command to insert the SUM function, you can type the function manually.

The SUM function setup (syntax) is: **SUM(number1**, [number2],...).

- It has one required argument:
**number1** - It also has optional arguments (enclosed in square brackets): [number2],..

These arguments can be cell references, or can be typed into the formula.

In the example above (**=SUM(A1:A4)**), there is one argument --
a reference to cells A1:A4.

Some Excel values look like numbers, but don't add up, because Excel thinks they are text. Sometimes, you can fix the problem with Paste Special. Watch this short video tutorial, to see the steps

For the written steps, and other ways to fix the problem, go to the Numbers Don't Add Up page.

In one quick step, you can calculate the row, column, and grand totals for a range of cell. Watch this short Excel Grand Totals video, to see how to do it. There are written instructions below the video.

- Select the range of cells, and the blank row below the range, and the blank cells in the column to the right (cells A1:D5 in the example below)
- Click the AutoSum button on the Ribbon's Home tab. A SUM formula will be automatically entered for each Total.

To see a running total in each row of an Excel list, you can use the SUM function, with the starting row locked as an absolute reference. There are slightly different steps below,

- for a running total in a worksheet list
- for a running total in a named Excel table

For a worksheet list (not a named Excel table), this video shows how to set up the running total formula, and lock the starting row. The written steps are below. For the video transcript, go to the Running Total Video page.

For a worksheet list (not a named Excel table), follow these steps to create a running total. In the screen shot below, amounts are entered in column C, and a running total is calculated in column D.

- Enter this formula in cell D2
**=SUM(C$2:C2)**

- Copy the formula down to cell D6

The formula uses an absolute reference to row 2 as the starting point
-- **C$2** -- and a relative reference to the ending point -- **C2**

This ensures that the starting point will not change when you copy the formula down to the rows below. Here is the formula in cell D6 -- the starting point has stayed the same and the ending point is in the current row -- C6

**=SUM(C$2:C6)**

For a named Excel table, we can't use the worksheet list formula in the previous section. First, I'll show you the problem with that formula, and then you'll see the formula that works in a named table.

After you enter the formula in cell D2 of the named Excel table, it automatically fills down, and the running total looks correct.

But, as soon as you start a new row at the bottom of the table, the formula in the last row changes.

Before the row was added, cell D6 had this formula:

**= SUM(C$2:C6)**

As soon as the next entry was started in row 7, the formula in D6 automatically changed. Now it has an incorrect ending reference to C7, instead of C6:

**=SUM(C$2:C7**)

As each new row is added, the formulas in the bottom rows keep changing, to show the latest row number.

To avoid that problem, we'll use a slightly different formula for a running total in a named Excel table.

In the screen shot below, amounts are entered in column C, and a running total is calculated in column D.

- Enter this formula in cell D2
**=SUM(C$1:[@Amt])**

- The formula automatically fills down to cell D6
- All cells in column D show the same formula

The formula uses an absolute reference to a heading cell as the starting point
-- **C$1**

- To prevent problems if a new data row is added at the top, the starting cell is in the table heading row
- Because the heading cell contains text, its value is treated as zero, and won't affect the running total

For the ending point, there is a structured table reference -- **[@Amt]**

- This is a reference to the Amt cell in the current row
- With that table cell reference, there's no problem when new rows are added to the Excel table

This screen shot shows that when a new row is started, cell C6 continues to show its original formula, and the running total amounts are correct in each row

If you insert a row directly above the SUM function in the previous example, the new row may not be included in the SUM. It may continue to sum cells A1:A4, and ignore A5. To ensure that new rows are included in the total, you can use the OFFSET function with the SUM function.

- Select cell A5.
- Enter the following formula:

**=SUM(A1:OFFSET(A5,-1,0))** - Press the Enter key to complete the entry.
- Insert a row above row 5
- Type a number in cell A5, and it will be included in the total in cell A6

Here are 3 ways to sum cells that match criteria, using the Excel SUMIF function:

- Match criterion using operator

The SUMIF function setup (syntax) is: **SUMIF(range**, **criteria**, [**sum_range**])

- SUMIF has two required arguments:
**range**- cells to check for the criteria**criteria**- value to use as criteria

- SUMIF also has one optional argument (in square
brackets):
- [
**sum_range**] - cells to sum -- if omitted, values in**range**are summed

- [

These arguments can be cell references, or can be typed into the formula.

You can calculate a total for rows that meet a specific criterion. In this example only the rows with Pen orders will be included in the total.

- Select the cell in which you want to see the total
- Type an equal sign (=) to start the formula
- Type: SUMIF(
- Select the cells that contain the values to check for the criterion. In this example, cells A2:A10 will be checked
- Type a comma, to separate the arguments
- Type the criterion. In this example, you're checking for text, so
type the word in double quotes: "Pen"

Note: upper and lower case are treated equally

- Type a comma, to separate the arguments
- Select the cells that contain the values to sum. In this example, cells B2:B10 will be summed
- The completed formula is:

**=SUMIF(A2:A10,"Pen",B2:B10)**

- Press the Enter key to complete the entry

**Note**: Instead of typing the criterion in a formula, you can refer
to a cell. For example, the formula in step 9 above could be changed to:

**=SUMIF(A2:A10, B12, B2:B10)
**if cell B12 contained the text —

You can add cells that contain a criterion as part of the cell's contents. In this example all Pen, Gel Pen, and Pencil orders will be summed, because they contain the string "pen".

- Select the cell in which you want to see the total (cell A12 in this example)
- Type an equal sign (=) to start the formula
- Type: SUMIF(
- Select the cells that contain the values to check for the criterion. In this example, cells A2:A10 will be checked
- Type a comma, to separate the arguments
- Type the criterion. In this example, you're checking for text, so
type the word in double quotes, with one or more asterisk (*) wildcard
characters: "*Pen*"

*Note: upper and lower case are treated equally*

- Type a comma, to separate the arguments
- Select the cells that contain the values to sum. In this example, cells B2:B10 will be summed
- Type a closing bracket. The completed formula is:
**=SUMIF(A2:A10,"*Pen*",B2:B10)**

- Press the Enter key to complete the entry
- The result will be 53, the total of rows that contain the string, "Pen"

**Note**: Instead of typing the criterion in a formula, you can refer
to a cell. For example, the formula in step 9 above could be changed to:

**=SUMIF(A2:A10,"*" & B12 & "*",B2:B10)
**if cell B12 contained the text —

You can use an operator with a criterion. In the examples below, see how to combine them in the SUMIF formula.

In this example only the rows where the number of sales reps is greater than or equal to ten will be included in the total.

- Select the cell in which you want to see the total
- Type an equal sign (=) to start the formula
- Type: SUMIF(
- Select the cells that contain the values to check for the criterion. In this example, cells B2:B10 will be checked
- Type a comma, to separate the arguments
- Type the criterion. In this example, you're checking for rows where the number of visits is greater than or equal to 10. The >= operator is used before the number, and the entire criterion is enclosed in double quotes.
- Type a comma, to separate the arguments
- Select the cells that contain the values to sum
- Type a closing bracket. The completed formula is:

**=SUMIF(B2:B10,">=10",C2:C10)**

- Press the Enter key to complete the entry
- The result will be 183, the total of rows with ten or more sales reps.

**Note**: Instead of typing the criterion in a formula, you can refer
to a cell. For example, the formula in step 9 above could be changed to:

**=SUMIF(B2:B10,">=" & B12,C2:C10)
**if cell B12 contained the number —

In this example only the rows for the previous 11 months, and the current month, will be included in the total. This creates a Rolling Total.

The dates are in column A, and the list must be sorted by date. The monthly amounts are in column B.

- Select the first cell in which you want to see the rolling total -- cell C2 in this example
- Enter the following formula, and press Enter:

=SUMIF(A$2:A2,">=" & DATE(YEAR(A2),MONTH(A2)-11,DAY(A2)),B$2:B2). - Copy the formula down to the last row with data.
- Each row shows the Rolling Total for the latest 12 months (if available)

**How It Works**

The formula checks the dates in column A, starting in row 2 (A$2), and down to the current row (A2)

=SUMIF(**A$2:A2**

The DATE function calculates the date that is 11 months prior to date in current row

**DATE(YEAR(A2),MONTH(A2)-11,DAY(A2)) **

The >= operator checks for dates that are greater than or equal to that date,

**">=" & **DATE(YEAR(A2),MONTH(A2)-11,DAY(A2))

For rows that meet the criterion, the formula sums the amounts in column B, starting in row 2 (B$2) down to the current row (B2)

**B$2:B2**

In Excel 2007 and later versions, you can use the SUMIFS function to calculate a total for rows that meet two or more criteria. Watch this short video to see the steps. There are written instructions below the video.

For the full video transcript, go to the Sum Amounts With 2 Criteria Video page.

The SUMIFS function setup (syntax) is: **SUMIFS(range**, **criteria**, [**sum_range**])

- SUMIFS has three required arguments:
**sum_range**- cells to check for the criteria**criteria_range1**- cells to check for the first criterion**criteria1**- value to use as first criterion

- Additional
**pairs**of**criteria_range**and**criteria**can be added, to sum based on multiple criteria

These arguments can be cell references, or can be typed into the formula.

In this example, the SUMIFS function will sum the amounts in column D, based on **2 criteria**:

- the status in column B is "Shipped"
- number of units in column C is greater than or equal to 10

Those criteria are entered in cells F6 (Shipped) and G6 (10)

Follow these steps to create the SUMIFS formula:

- Select the cell in which you want to see the total
- Type an equal sign (=) to start the formula
- Type: SUMIFS(
- Select the cells that contain the values to sum. In this example, cells D3:D10 will be summed
- Type a comma, then select the cells that contain the values to check for the first criterion. In this example, cells B3:B10 will be checked
- Type a comma, and then type the first criterion, "Shipped"
- Type a comma, then select the cells that contain the values to check for the second criterion. In this example, cells B2:B6 will be checked
- Type a comma, and then type the second criterion: " >=" & 10
- Finish with a closing bracket: )
- The completed formula is:

**=SUMIFS(D3:D10,B3:B10,"Shipped",C3:C10,">=" & 10)** - Press the Enter key to complete the entry

If you create formulas with table references, and then try to copy those formulas to adjacent columns, you might run into problems. This video shows the problem, and two ways to prevent it. There are written steps below the video.

In this sales summary, there is a SUMIFS formula in cell C5, which is showing the correct total for Bars sales in the East region.

**=SUMIFS(Sales_Data[Quantity], Sales_Data[Region],$B5, Sales_Data[Category],C$4)**

However, if you point to the fill handle in cell C5, and drag to the right, the formula shows an incorrect total in cell D5.

If you check the formula in cell D5, all of the table references have shifted one column to the right, because the formula was dragged one column to the right.

**=SUMIFS(Sales_Data[TotalCost], Sales_Data[Category],$B5, Sales_Data[Product],D$4)**

- Instead of Quantity, the formula is summing the Total Cost column
- Instead of looking for East in the Region column, it's looking in Category
- Instead of looking for Cookies in the Category column, it's looking in Product

None of those criteria are found, so the result is zero.

To prevent this problem of shifting table references, don't drag the fill handle to copy across.

Instead, use one of the following methods:

- Select the cell with the formula, and the cells to the right, where you want to copy the formula
- Press Ctrl+R to fill the formula to the right

- Select the cell with the formula, and press Ctrl+C to copy it
- Select all the cells where you want to copy the formula
- Press Ctrl+V to paste the formula

In the list below, you could use a SUMIFS formula to total the rows where:

- City is New York

**AND**

- Category is Bars

The formula in cell G9 would be:

**=SUMIFS(D4:D15,B4:B15,G4,C4:C15,G6)**

Instead of just one category though, we would like to calculate the total for two or more categories. In this example, we'll calculate the total where:

- city is New York
**AND**Category is Cookies

**OR**

- city is New York
**AND**Category is Bars

The two categories are entered in cells G6:G7 on the worksheet.

To calculate the total, we'll wrap the SUMIFS formula with a SUM function, and enter the formula as an array.

- Select the cell in which you want to see the total -- G9 in this example
- To start the formula, type:
**=SUM(SUMIFS(** - Select the cells that contain the values to sum. In this example,
cells
**D4:D15**will be summed - Type a
**comma**, then select the cells that contain the values to check for the first criterion. In this example, cells**B4:B15**will be checked -- they contain the city names - Type a
**comma**, and then click on the cell with the first criterion --**G4** - Type a
**comma**, then select the cells that contain the values to check for the second criterion. In this example, cells**C4:C15**will be checked -- they have the category - Type a
**comma**, and then select the cells with the list for the second criterion --**G6:G7** - Finish with 2 closing brackets:
**))** - The completed formula in cell G9 is:

**=SUM(SUMIFS(D4:D15,B4:B15,G4,C4:C15,G6:G7))**

- Press the
**Ctrl + Shift + Enter**keys to**array-enter**the formula -- the result will not be correct if you simply press the Enter key. - Curly brackets will be automatically added at the beginning and end of the formula, to show that it is array-entered. Do not type this brackets yourself.

In Excel 2003 and earlier, you can use the SUMPRODUCT function to calculate a total for rows that meet two or more criteria. If you're using Excel 2007 or later, you should use the SUMIFS function, as described in the previous section.

In this example only the rows where the status is "Active" and the number of visits is greater than or equal to ten will be included in the total.

- Select the cell in which you want to see the total
- Type an equal sign (=) to start the formula
- Type: SUMPRODUCT(--(
- Select the cells that contain the values to check for the first criterion. In this example, cells A2:A6 will be checked
- Type the first criterion: ="Active"
- Type ),--(
- Select the cells that contain the values to check for the second criterion. In this example, cells B2:B6 will be checked
- Type the second criterion: >=10
- Type ),--(
- Select the cells that contain the values to sum. In this example, cells C2:C6 will be summed
- Finish with closing brackets: ))
- The completed formula is:

**=SUMPRODUCT(--(A2:A6="Active"), --(B2:B6>=10),--(C2:C6))**

- Press the Enter key to complete the entry

Use the SUM function and LARGE functions together, to add the largest numbers in the list.

If a few numbers are to be summed, e.g. top 3, you can type the numbers into the formula. For example:

**=SUM(LARGE(A1:A7,{1,2,3}))**

The result is 70+60+50 = 180

**Note**: The second 50 is not included in the result, even though
it is tied for 3rd place.

If many top numbers are to be summed you can include the INDIRECT function in the formula with the SUM function. In the INDIRECT function, use row numbers that represent the numbers you want to include. In this example, rows 1:10 are used, so the top 10 numbers in the referenced range will be summed.

- Type the formula:

**=SUM(LARGE(A1:A50,ROW(INDIRECT("1:10"))))** - This is an array formula, and must be array-entered. To do this, hold the Ctrl and Shift keys, and press Enter

If a variable number of top numbers are to be summed you can include the INDIRECT function in the formula with the SUM function, as shown above, and refer to a cell that holds the variable..

- In cell C1, type the number of top cells, e.g. 10
- Type the formula:

**=SUM(LARGE(A1:A7,ROW(INDIRECT("1:"&C1))))** - This is an array formula, and must be array-entered. To do this, hold the Ctrl and Shift keys, and press Enter

To sum amounts based on a date range, you can use the SUMIFS function in Excel 2007 or later versions. Watch this video to see the steps, and the written instructions are below the video.

To total the amounts in a specific date range, use the SUMIFS function (Excel 2007 and later) or the SUMIF function. There are two examples below:

In this example, a Start date and an End date are entered on the worksheet. Dates are in column A, and units sold are in column B.

See more Date Range examples on the Sum or Count for a Date Range page.

For Excel 2007, and later versions, you can use the SUMIFS function to calculate a total based on multiple criteria. We'll use a SUMIFS formula to total all the units where the sales date is:

- on or after the Start date
- AND

- on or before the End date.

Here is the formula that is entered in cell D5:

**=SUMIFS($B$2:$B$9,$A$2:$A$9,">="
& $D$2, $A$2:$A$9,"<="
& $E$2)**

- The first argument,
**$B$2:$B$9**, is the range with the numbers that we want to sum. - The 2nd argument,
**$A$2:$A$9**, is the range to check for criteria 1. - The 3rd argument,
**">=" & $D$2**, is the range with the value for criteria 1 (the Start date), and the operator to use with that value (greater than or equal to) - The 4th argument,
**$A$2:$A$9**, is the range to check for criteria 2. - The 5th argument,
**"<=" & $E$2**, is the range with the value for criteria 2 (the End date), and the operator to use with that value (less than or equal to)

In this example, the result for the selected date range is a total of 494 units sold. To verify, you can select cells B3:B6, and look at the total shown in Excel's Status Bar.

To get the total units for a different date range, change the Start date in cell D2, and/or the End date in cell E2.

For Excel 2003, and earier versions, you can use the SUMIF function to calculate a total based on a single criterion. We'll use one SUMIF formula to total all the units where the sales date is:

- on or after the Start date

Then we'll use another SUMIF formula to subtract any values where there date is

- after the End date.

Here is the formula that is entered in cell D5:

**=SUMIF($A$2:$A$9,">="
&$D$2,$B$2:$B$9)
- SUMIF($A$2:$A$9,">"
&$E$2,$B$2:$B$9)**

- The range,
**$A$2:$A$9**, contains the numbers that we want to sum. - The criteria,
**">=" & $D$2**, is the range with the Start date, and the operator to use with that value (greater than or equal to) - The range,
**$B$2:$B$9**, is the range to check for the date - The criteria,
**">" & $E$2**, is the range with the End date, and the operator to use with that value (greater than)

In this example, the result for the selected date range is a total of 494 units sold. To verify, you can select cells B3:B6, and look at the total shown in Excel's Status Bar.

To get the total units for a different date range, change the Start date in cell D2, and/or the End date in cell E2.

After you filter the rows in a list, you can use the SUBTOTAL function, instead of the SUM function, to sum the numbers in the visible rows.

- Apply an AutoFilter to the table. There are instructions here -- AutoFilter Basics
- Filter at least one of the columns in the table. In this example, the first column has been filtered for Binders.
- Select the cell immediately below the column you want to sum.
- Click the AutoSum button on the Ribbon's Home tab.
- If you want the SUBTOTAL function in a cell other than the one directly below the filtered list, you can type the formula, instead of using the AutoSum button.

- A SUBTOTAL formula will be automatically inserted, totalling the visible cells in the column
- The first argument in the SUBTOTAL function is a function number, that specifies how the numbers should be calculated. There is a 9 in this example, which tells Excel to SUM the numbers.
- Other function numbers can be used, such as 1 for AVERAGE, and 3 for COUNTA. The full list is shown in my blog post Total a Filtered List.
- Press the Enter key to complete the formula entry.

**Note**: In Excel 2003 and later versions, you can use the formula:

** =SUBTOTAL(109,B2:B9)**

to subtotal visible cells in a range where rows have been manually hidden,
or filtered.

The first argument in the SUBTOTAL function is a function number, that specifies how the numbers should be calculated. There are 11 functions that you can use as the first argument in the SUBTOTAL function. The list is alphabetical, so that might help you remember some of the numbers, without going to Excel's Help every time.

The functions are each listed twice. The first group of functions is numbered 1-11.

The functions are each listed twice. The second group of functions is numbered 101-111.

The AGGREGATE function, introduced in Excel 2010, is similar to the SUBTOTAL function, but it has more functions, and can ignore error values, as well as hidden rows in the data.

Watch this video to see the steps for setting up an AGGREGATE formula, and the written instructions are below the video.

After you filter the rows in a list, you can use the AGGREGATE function, instead of the SUM function, to sum the numbers in the visible rows. This function was introduced in Excel 2010.

Similar to the SUBTOTAL function, AGGREGATE ignores hidden rows, and offers several functions, like SUM or AVERAGE, for the selected data. However, it has 19 functions, compared to SUBTOTAL's 11 functions.

Unlike the SUBTOTAL function, AGGREGATE can be set to ignore errors, as well as hidden rows, and nested SUBTOTAL and AGGREGATE functions.

To sum the values in a filtered list, and ignore hidden rows and errors:

- Select the cell where you want the sum
- Type =AGGREGATE(
- In the list of functions, double-click on 9 - SUM, to add 9 as the first argument.
- Type a comma, and in the list of options, double-click on option 3 or option 7. In this example, 3 is the second argument, and the result will ignore hidden rows, errors, and nested AGGREGATE and SUBTOTAL functions.
- Type a comma, and select the range of cells that contain the data -- D2:D7 in this example.
- Type a bracket, to complete the formula, and press the Enter key.

The completed formula is: **=AGGREGATE(9,3,D2:D7)**

Laurent Longre created a formula that lets you work with visible rows after a filter. For information see, Power Formula Technique in this article at John Walkenbach's web site (no longer available).

Incorporating that technique, SUMPRODUCT can be used to sum visible items in a filtered table. In the following example, column D has been filtered for amounts greater than 100. The following formula will sum the Total amounts, in rows that contain "Pen" in column A.

- Filter column D for amounts greater than 100.
- In cell A12, type: Pen
- In cell B12, enter the following formula:
**=SUMPRODUCT(SUBTOTAL(3,OFFSET(A1:A10,ROW(A1:A10)**

-MIN(ROW(A1:A10)),,1)), --(A1:A10=A12),D1:D10)

- Press the Enter key to complete the formula entry.

For another example of using SUMPRODUCT and SUBTOTAL together, see my blog post, Subtotal and Sumproduct with Filter. Sam shared his technique for doing additional sums or counts, based on the visible data in a filtered table.

Sam's workbook has a list with Product, Region and Amount fields. He created dynamic named ranges for the entries in each field, using INDEX and COUNTA.

You can get Sam's workbook in the Downloads section, below.

**SUM Examples**: Download the zipped Sum functions sample workbook. The workbook contains the examples for SUM, SUMIF, SUMIFS, SUMPRODUCT, SUBTOTAL and AGGREGATE functions. The zipped file is in xlsx format, and does not contain any macros.**SUMIFS Orders**: Download the SUMIFS Orders sample workbook, to follow along with the Sum Amounts with 2 Criteria video. The zipped file is in xlsx format, and does not contain any macros.**7 Ways to Sum:**Download the 7 Ways to Sum sample workbook, to follow along with the 7 Ways to Sum video. The zipped file is in xlsx format, and does not contain any macros.**Sam's Workbook**: To see Sam's workbook and formulas, for doing additional sums or counts, based on the visible data in a filtered table, download the**SUMPRODUCT SUBTOTAL sample file**.**Table References**: To see the problem with copying formulas with table references, download the**Table Reference Problem workbook.**The zipped file is in xlsx format, and does not contain any macros

Last updated: February 16, 2022 3:30 PM